Descargar las actualizaciones de Office 2013

 Mar, 01 - 2014   sin comentarios   Microsoft Office

Hola que tal amigos pues en esta ocasión vamos a ver con un script como podemos descargar las actualizaciones de Office 2013 para poder implementarlas en otros entornos, el script muestra la descarga de las actualizaciones en un archivo .MSP de los diferentes componentes de Office 2013.

una vez descargadas las podemos utilizar en un recurso compartido de Office 2013 en la carpeta updates.

lo que tenemos que hacer es copiar el siguiente código y lo guardamos como CollectUpdates.vbs

 

Dim oMsi,oFso,oWShell

Dim Patches,SumInfo

Dim patch,record,msp

Dim qView

Dim sTargetFolder,sMessage

Const OFFICEID = "000-0000000FF1CE}"

Const PRODUCTCODE_EMPTY = ""

Const MACHINESID = ""

Const MSIINSTALLCONTEXT_MACHINE = 4

Const MSIPATCHSTATE_APPLIED = 1

Const MSIOPENDATABASEMODE_PATCHFILE = 32

Const PID_SUBJECT = 3 'Displayname

Const PID_TEMPLATES = 7 'PatchTargets

Set oMsi = CreateObject("WindowsInstaller.Installer")

Set oFso = CreateObject("Scripting.FileSystemObject")

Set oWShell = CreateObject("Wscript.Shell")

 

'Create the target folder

sTargetFolder = oWShell.ExpandEnvironmentStrings("%TEMP%")&"\Updates"

If Not oFso.FolderExists(sTargetFolder) Then oFso.CreateFolder sTargetFolder

sMessage = "Patches are being copied to the %Temp%\Updates folder." & vbCrLf & "A Windows Explorer window will open after the script has run."

oWShell.Popup sMessage,20,"Office Patch Collector"

 

'Get all applied patches

Set Patches = oMsi.PatchesEx(PRODUCTCODE_EMPTY,MACHINESID,MSIINSTALLCONTEXT_MACHINE,MSIPATCHSTATE_APPLIED)

 

On Error Resume Next

'Enum the patches

For Each patch in Patches

   If Not Err = 0 Then Err.Clear

    'Connect to the patch file

    Set msp = oMsi.OpenDatabase(patch.PatchProperty("LocalPackage"),MSIOPENDATABASEMODE_PATCHFILE)

    Set SumInfo = msp.SummaryInformation

    If Err = 0 Then

        If InStr(SumInfo.Property(PID_TEMPLATES),OFFICEID)>0 Then

            'Get the original patch name

            Set qView = msp.OpenView("SELECT Property,Value FROM MsiPatchMetadata WHERE Property='StdPackageName'")

            qView.Execute : Set record = qView.Fetch()

            'Copy and rename the patch to the original file name

            oFso.CopyFile patch.PatchProperty("LocalPackage"),sTargetFolder&"\"&record.StringData(2),TRUE

        End If

    End If 'Err = 0

Next 'patch

oWShell.Run "explorer /e,"&chr(34)&sTargetFolder&chr(34)

el archivo lo puedes descargar desde aquí: http://1drv.ms/1fxFbQv

cuando ejecutamos el archivo, automáticamente este los descarga desde la carpeta temporal de Windows %TEMP%\updates podemos acceder a ella desde la opción buscar tal y como se muestra la imagen.

1

aquí las actualizaciones descargadas.

3

estos archivos los podemos copiar a la carpeta de actualizaciones de office ubicada en la red para poder distribuirlos mas adelante.

para mas información visita: http://technet.microsoft.com/es-es/library/cc178995.aspx

felices despliegues 🙂

MAP L.I. Jesús Octavio Rodríguez de Santiago

https://www.facebook.com/freelance.deployment
http://www.freelance-it.com.mx
@freelanceitags

 

 


Artículos relacionados

Deja un comentario